File:
[local] /
rpl /
lapack /
blas /
dsymm.f
Revision
1.10:
download - view:
text,
annotated -
select for diffs -
revision graph
Mon Jan 27 09:28:13 2014 UTC (11 years, 3 months ago) by
bertrand
Branches:
MAIN
CVS tags:
rpl-4_1_24,
rpl-4_1_23,
rpl-4_1_22,
rpl-4_1_21,
rpl-4_1_20,
rpl-4_1_19,
rpl-4_1_18,
rpl-4_1_17,
HEAD
Cohérence.
1: *> \brief \b DSYMM
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: * Definition:
9: * ===========
10: *
11: * SUBROUTINE DSYMM(SIDE,UPLO,M,N,ALPHA,A,LDA,B,LDB,BETA,C,LDC)
12: *
13: * .. Scalar Arguments ..
14: * DOUBLE PRECISION ALPHA,BETA
15: * INTEGER LDA,LDB,LDC,M,N
16: * CHARACTER SIDE,UPLO
17: * ..
18: * .. Array Arguments ..
19: * DOUBLE PRECISION A(LDA,*),B(LDB,*),C(LDC,*)
20: * ..
21: *
22: *
23: *> \par Purpose:
24: * =============
25: *>
26: *> \verbatim
27: *>
28: *> DSYMM performs one of the matrix-matrix operations
29: *>
30: *> C := alpha*A*B + beta*C,
31: *>
32: *> or
33: *>
34: *> C := alpha*B*A + beta*C,
35: *>
36: *> where alpha and beta are scalars, A is a symmetric matrix and B and
37: *> C are m by n matrices.
38: *> \endverbatim
39: *
40: * Arguments:
41: * ==========
42: *
43: *> \param[in] SIDE
44: *> \verbatim
45: *> SIDE is CHARACTER*1
46: *> On entry, SIDE specifies whether the symmetric matrix A
47: *> appears on the left or right in the operation as follows:
48: *>
49: *> SIDE = 'L' or 'l' C := alpha*A*B + beta*C,
50: *>
51: *> SIDE = 'R' or 'r' C := alpha*B*A + beta*C,
52: *> \endverbatim
53: *>
54: *> \param[in] UPLO
55: *> \verbatim
56: *> UPLO is CHARACTER*1
57: *> On entry, UPLO specifies whether the upper or lower
58: *> triangular part of the symmetric matrix A is to be
59: *> referenced as follows:
60: *>
61: *> UPLO = 'U' or 'u' Only the upper triangular part of the
62: *> symmetric matrix is to be referenced.
63: *>
64: *> UPLO = 'L' or 'l' Only the lower triangular part of the
65: *> symmetric matrix is to be referenced.
66: *> \endverbatim
67: *>
68: *> \param[in] M
69: *> \verbatim
70: *> M is INTEGER
71: *> On entry, M specifies the number of rows of the matrix C.
72: *> M must be at least zero.
73: *> \endverbatim
74: *>
75: *> \param[in] N
76: *> \verbatim
77: *> N is INTEGER
78: *> On entry, N specifies the number of columns of the matrix C.
79: *> N must be at least zero.
80: *> \endverbatim
81: *>
82: *> \param[in] ALPHA
83: *> \verbatim
84: *> ALPHA is DOUBLE PRECISION.
85: *> On entry, ALPHA specifies the scalar alpha.
86: *> \endverbatim
87: *>
88: *> \param[in] A
89: *> \verbatim
90: *> A is DOUBLE PRECISION array of DIMENSION ( LDA, ka ), where ka is
91: *> m when SIDE = 'L' or 'l' and is n otherwise.
92: *> Before entry with SIDE = 'L' or 'l', the m by m part of
93: *> the array A must contain the symmetric matrix, such that
94: *> when UPLO = 'U' or 'u', the leading m by m upper triangular
95: *> part of the array A must contain the upper triangular part
96: *> of the symmetric matrix and the strictly lower triangular
97: *> part of A is not referenced, and when UPLO = 'L' or 'l',
98: *> the leading m by m lower triangular part of the array A
99: *> must contain the lower triangular part of the symmetric
100: *> matrix and the strictly upper triangular part of A is not
101: *> referenced.
102: *> Before entry with SIDE = 'R' or 'r', the n by n part of
103: *> the array A must contain the symmetric matrix, such that
104: *> when UPLO = 'U' or 'u', the leading n by n upper triangular
105: *> part of the array A must contain the upper triangular part
106: *> of the symmetric matrix and the strictly lower triangular
107: *> part of A is not referenced, and when UPLO = 'L' or 'l',
108: *> the leading n by n lower triangular part of the array A
109: *> must contain the lower triangular part of the symmetric
110: *> matrix and the strictly upper triangular part of A is not
111: *> referenced.
112: *> \endverbatim
113: *>
114: *> \param[in] LDA
115: *> \verbatim
116: *> LDA is INTEGER
117: *> On entry, LDA specifies the first dimension of A as declared
118: *> in the calling (sub) program. When SIDE = 'L' or 'l' then
119: *> LDA must be at least max( 1, m ), otherwise LDA must be at
120: *> least max( 1, n ).
121: *> \endverbatim
122: *>
123: *> \param[in] B
124: *> \verbatim
125: *> B is DOUBLE PRECISION array of DIMENSION ( LDB, n ).
126: *> Before entry, the leading m by n part of the array B must
127: *> contain the matrix B.
128: *> \endverbatim
129: *>
130: *> \param[in] LDB
131: *> \verbatim
132: *> LDB is INTEGER
133: *> On entry, LDB specifies the first dimension of B as declared
134: *> in the calling (sub) program. LDB must be at least
135: *> max( 1, m ).
136: *> \endverbatim
137: *>
138: *> \param[in] BETA
139: *> \verbatim
140: *> BETA is DOUBLE PRECISION.
141: *> On entry, BETA specifies the scalar beta. When BETA is
142: *> supplied as zero then C need not be set on input.
143: *> \endverbatim
144: *>
145: *> \param[in,out] C
146: *> \verbatim
147: *> C is DOUBLE PRECISION array of DIMENSION ( LDC, n ).
148: *> Before entry, the leading m by n part of the array C must
149: *> contain the matrix C, except when beta is zero, in which
150: *> case C need not be set on entry.
151: *> On exit, the array C is overwritten by the m by n updated
152: *> matrix.
153: *> \endverbatim
154: *>
155: *> \param[in] LDC
156: *> \verbatim
157: *> LDC is INTEGER
158: *> On entry, LDC specifies the first dimension of C as declared
159: *> in the calling (sub) program. LDC must be at least
160: *> max( 1, m ).
161: *> \endverbatim
162: *
163: * Authors:
164: * ========
165: *
166: *> \author Univ. of Tennessee
167: *> \author Univ. of California Berkeley
168: *> \author Univ. of Colorado Denver
169: *> \author NAG Ltd.
170: *
171: *> \date November 2011
172: *
173: *> \ingroup double_blas_level3
174: *
175: *> \par Further Details:
176: * =====================
177: *>
178: *> \verbatim
179: *>
180: *> Level 3 Blas routine.
181: *>
182: *> -- Written on 8-February-1989.
183: *> Jack Dongarra, Argonne National Laboratory.
184: *> Iain Duff, AERE Harwell.
185: *> Jeremy Du Croz, Numerical Algorithms Group Ltd.
186: *> Sven Hammarling, Numerical Algorithms Group Ltd.
187: *> \endverbatim
188: *>
189: * =====================================================================
190: SUBROUTINE DSYMM(SIDE,UPLO,M,N,ALPHA,A,LDA,B,LDB,BETA,C,LDC)
191: *
192: * -- Reference BLAS level3 routine (version 3.4.0) --
193: * -- Reference BLAS is a software package provided by Univ. of Tennessee, --
194: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
195: * November 2011
196: *
197: * .. Scalar Arguments ..
198: DOUBLE PRECISION ALPHA,BETA
199: INTEGER LDA,LDB,LDC,M,N
200: CHARACTER SIDE,UPLO
201: * ..
202: * .. Array Arguments ..
203: DOUBLE PRECISION A(LDA,*),B(LDB,*),C(LDC,*)
204: * ..
205: *
206: * =====================================================================
207: *
208: * .. External Functions ..
209: LOGICAL LSAME
210: EXTERNAL LSAME
211: * ..
212: * .. External Subroutines ..
213: EXTERNAL XERBLA
214: * ..
215: * .. Intrinsic Functions ..
216: INTRINSIC MAX
217: * ..
218: * .. Local Scalars ..
219: DOUBLE PRECISION TEMP1,TEMP2
220: INTEGER I,INFO,J,K,NROWA
221: LOGICAL UPPER
222: * ..
223: * .. Parameters ..
224: DOUBLE PRECISION ONE,ZERO
225: PARAMETER (ONE=1.0D+0,ZERO=0.0D+0)
226: * ..
227: *
228: * Set NROWA as the number of rows of A.
229: *
230: IF (LSAME(SIDE,'L')) THEN
231: NROWA = M
232: ELSE
233: NROWA = N
234: END IF
235: UPPER = LSAME(UPLO,'U')
236: *
237: * Test the input parameters.
238: *
239: INFO = 0
240: IF ((.NOT.LSAME(SIDE,'L')) .AND. (.NOT.LSAME(SIDE,'R'))) THEN
241: INFO = 1
242: ELSE IF ((.NOT.UPPER) .AND. (.NOT.LSAME(UPLO,'L'))) THEN
243: INFO = 2
244: ELSE IF (M.LT.0) THEN
245: INFO = 3
246: ELSE IF (N.LT.0) THEN
247: INFO = 4
248: ELSE IF (LDA.LT.MAX(1,NROWA)) THEN
249: INFO = 7
250: ELSE IF (LDB.LT.MAX(1,M)) THEN
251: INFO = 9
252: ELSE IF (LDC.LT.MAX(1,M)) THEN
253: INFO = 12
254: END IF
255: IF (INFO.NE.0) THEN
256: CALL XERBLA('DSYMM ',INFO)
257: RETURN
258: END IF
259: *
260: * Quick return if possible.
261: *
262: IF ((M.EQ.0) .OR. (N.EQ.0) .OR.
263: + ((ALPHA.EQ.ZERO).AND. (BETA.EQ.ONE))) RETURN
264: *
265: * And when alpha.eq.zero.
266: *
267: IF (ALPHA.EQ.ZERO) THEN
268: IF (BETA.EQ.ZERO) THEN
269: DO 20 J = 1,N
270: DO 10 I = 1,M
271: C(I,J) = ZERO
272: 10 CONTINUE
273: 20 CONTINUE
274: ELSE
275: DO 40 J = 1,N
276: DO 30 I = 1,M
277: C(I,J) = BETA*C(I,J)
278: 30 CONTINUE
279: 40 CONTINUE
280: END IF
281: RETURN
282: END IF
283: *
284: * Start the operations.
285: *
286: IF (LSAME(SIDE,'L')) THEN
287: *
288: * Form C := alpha*A*B + beta*C.
289: *
290: IF (UPPER) THEN
291: DO 70 J = 1,N
292: DO 60 I = 1,M
293: TEMP1 = ALPHA*B(I,J)
294: TEMP2 = ZERO
295: DO 50 K = 1,I - 1
296: C(K,J) = C(K,J) + TEMP1*A(K,I)
297: TEMP2 = TEMP2 + B(K,J)*A(K,I)
298: 50 CONTINUE
299: IF (BETA.EQ.ZERO) THEN
300: C(I,J) = TEMP1*A(I,I) + ALPHA*TEMP2
301: ELSE
302: C(I,J) = BETA*C(I,J) + TEMP1*A(I,I) +
303: + ALPHA*TEMP2
304: END IF
305: 60 CONTINUE
306: 70 CONTINUE
307: ELSE
308: DO 100 J = 1,N
309: DO 90 I = M,1,-1
310: TEMP1 = ALPHA*B(I,J)
311: TEMP2 = ZERO
312: DO 80 K = I + 1,M
313: C(K,J) = C(K,J) + TEMP1*A(K,I)
314: TEMP2 = TEMP2 + B(K,J)*A(K,I)
315: 80 CONTINUE
316: IF (BETA.EQ.ZERO) THEN
317: C(I,J) = TEMP1*A(I,I) + ALPHA*TEMP2
318: ELSE
319: C(I,J) = BETA*C(I,J) + TEMP1*A(I,I) +
320: + ALPHA*TEMP2
321: END IF
322: 90 CONTINUE
323: 100 CONTINUE
324: END IF
325: ELSE
326: *
327: * Form C := alpha*B*A + beta*C.
328: *
329: DO 170 J = 1,N
330: TEMP1 = ALPHA*A(J,J)
331: IF (BETA.EQ.ZERO) THEN
332: DO 110 I = 1,M
333: C(I,J) = TEMP1*B(I,J)
334: 110 CONTINUE
335: ELSE
336: DO 120 I = 1,M
337: C(I,J) = BETA*C(I,J) + TEMP1*B(I,J)
338: 120 CONTINUE
339: END IF
340: DO 140 K = 1,J - 1
341: IF (UPPER) THEN
342: TEMP1 = ALPHA*A(K,J)
343: ELSE
344: TEMP1 = ALPHA*A(J,K)
345: END IF
346: DO 130 I = 1,M
347: C(I,J) = C(I,J) + TEMP1*B(I,K)
348: 130 CONTINUE
349: 140 CONTINUE
350: DO 160 K = J + 1,N
351: IF (UPPER) THEN
352: TEMP1 = ALPHA*A(J,K)
353: ELSE
354: TEMP1 = ALPHA*A(K,J)
355: END IF
356: DO 150 I = 1,M
357: C(I,J) = C(I,J) + TEMP1*B(I,K)
358: 150 CONTINUE
359: 160 CONTINUE
360: 170 CONTINUE
361: END IF
362: *
363: RETURN
364: *
365: * End of DSYMM .
366: *
367: END
CVSweb interface <joel.bertrand@systella.fr>
![[BACK]](/cvsweb/icons/back.gif){kind=icon}
Return to dsymm.f CVS log ![[TXT]](/cvsweb/icons/text.gif){kind=icon}
![[DIR]](/cvsweb/icons/dir.gif){kind=icon}
Up to [local] / rpl / lapack / blas