1: *> \brief \b DSWAP
2: *
3: * =========== DOCUMENTATION ===========
4: *
5: * Online html documentation available at
6: * http://www.netlib.org/lapack/explore-html/
7: *
8: * Definition:
9: * ===========
10: *
11: * SUBROUTINE DSWAP(N,DX,INCX,DY,INCY)
12: *
13: * .. Scalar Arguments ..
14: * INTEGER INCX,INCY,N
15: * ..
16: * .. Array Arguments ..
17: * DOUBLE PRECISION DX(*),DY(*)
18: * ..
19: *
20: *
21: *> \par Purpose:
22: * =============
23: *>
24: *> \verbatim
25: *>
26: *> DSWAP interchanges two vectors.
27: *> uses unrolled loops for increments equal to 1.
28: *> \endverbatim
29: *
30: * Arguments:
31: * ==========
32: *
33: *> \param[in] N
34: *> \verbatim
35: *> N is INTEGER
36: *> number of elements in input vector(s)
37: *> \endverbatim
38: *>
39: *> \param[in,out] DX
40: *> \verbatim
41: *> DX is DOUBLE PRECISION array, dimension ( 1 + ( N - 1 )*abs( INCX ) )
42: *> \endverbatim
43: *>
44: *> \param[in] INCX
45: *> \verbatim
46: *> INCX is INTEGER
47: *> storage spacing between elements of DX
48: *> \endverbatim
49: *>
50: *> \param[in,out] DY
51: *> \verbatim
52: *> DY is DOUBLE PRECISION array, dimension ( 1 + ( N - 1 )*abs( INCY ) )
53: *> \endverbatim
54: *>
55: *> \param[in] INCY
56: *> \verbatim
57: *> INCY is INTEGER
58: *> storage spacing between elements of DY
59: *> \endverbatim
60: *
61: * Authors:
62: * ========
63: *
64: *> \author Univ. of Tennessee
65: *> \author Univ. of California Berkeley
66: *> \author Univ. of Colorado Denver
67: *> \author NAG Ltd.
68: *
69: *> \ingroup double_blas_level1
70: *
71: *> \par Further Details:
72: * =====================
73: *>
74: *> \verbatim
75: *>
76: *> jack dongarra, linpack, 3/11/78.
77: *> modified 12/3/93, array(1) declarations changed to array(*)
78: *> \endverbatim
79: *>
80: * =====================================================================
81: SUBROUTINE DSWAP(N,DX,INCX,DY,INCY)
82: *
83: * -- Reference BLAS level1 routine --
84: * -- Reference BLAS is a software package provided by Univ. of Tennessee, --
85: * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
86: *
87: * .. Scalar Arguments ..
88: INTEGER INCX,INCY,N
89: * ..
90: * .. Array Arguments ..
91: DOUBLE PRECISION DX(*),DY(*)
92: * ..
93: *
94: * =====================================================================
95: *
96: * .. Local Scalars ..
97: DOUBLE PRECISION DTEMP
98: INTEGER I,IX,IY,M,MP1
99: * ..
100: * .. Intrinsic Functions ..
101: INTRINSIC MOD
102: * ..
103: IF (N.LE.0) RETURN
104: IF (INCX.EQ.1 .AND. INCY.EQ.1) THEN
105: *
106: * code for both increments equal to 1
107: *
108: *
109: * clean-up loop
110: *
111: M = MOD(N,3)
112: IF (M.NE.0) THEN
113: DO I = 1,M
114: DTEMP = DX(I)
115: DX(I) = DY(I)
116: DY(I) = DTEMP
117: END DO
118: IF (N.LT.3) RETURN
119: END IF
120: MP1 = M + 1
121: DO I = MP1,N,3
122: DTEMP = DX(I)
123: DX(I) = DY(I)
124: DY(I) = DTEMP
125: DTEMP = DX(I+1)
126: DX(I+1) = DY(I+1)
127: DY(I+1) = DTEMP
128: DTEMP = DX(I+2)
129: DX(I+2) = DY(I+2)
130: DY(I+2) = DTEMP
131: END DO
132: ELSE
133: *
134: * code for unequal increments or equal increments not equal
135: * to 1
136: *
137: IX = 1
138: IY = 1
139: IF (INCX.LT.0) IX = (-N+1)*INCX + 1
140: IF (INCY.LT.0) IY = (-N+1)*INCY + 1
141: DO I = 1,N
142: DTEMP = DX(IX)
143: DX(IX) = DY(IY)
144: DY(IY) = DTEMP
145: IX = IX + INCX
146: IY = IY + INCY
147: END DO
148: END IF
149: RETURN
150: *
151: * End of DSWAP
152: *
153: END
CVSweb interface <joel.bertrand@systella.fr>