Return to ddot.f CVS log

Up to [local] / rpl / lapack / blas

Cohérence.

    1: *> \brief \b DDOT
    2: *
    3: *  =========== DOCUMENTATION ===========
    4: *
    5: * Online html documentation available at 
    6: *            http://www.netlib.org/lapack/explore-html/ 
    7: *
    8: *  Definition:
    9: *  ===========
   10: *
   11: *       DOUBLE PRECISION FUNCTION DDOT(N,DX,INCX,DY,INCY)
   12: * 
   13: *       .. Scalar Arguments ..
   14: *       INTEGER INCX,INCY,N
   15: *       ..
   16: *       .. Array Arguments ..
   17: *       DOUBLE PRECISION DX(*),DY(*)
   18: *       ..
   19: *  
   20: *
   21: *> \par Purpose:
   22: *  =============
   23: *>
   24: *> \verbatim
   25: *>
   26: *>    DDOT forms the dot product of two vectors.
   27: *>    uses unrolled loops for increments equal to one.
   28: *> \endverbatim
   29: *
   30: *  Authors:
   31: *  ========
   32: *
   33: *> \author Univ. of Tennessee 
   34: *> \author Univ. of California Berkeley 
   35: *> \author Univ. of Colorado Denver 
   36: *> \author NAG Ltd. 
   37: *
   38: *> \date November 2011
   39: *
   40: *> \ingroup double_blas_level1
   41: *
   42: *> \par Further Details:
   43: *  =====================
   44: *>
   45: *> \verbatim
   46: *>
   47: *>     jack dongarra, linpack, 3/11/78.
   48: *>     modified 12/3/93, array(1) declarations changed to array(*)
   49: *> \endverbatim
   50: *>
   51: *  =====================================================================
   52:       DOUBLE PRECISION FUNCTION DDOT(N,DX,INCX,DY,INCY)
   53: *
   54: *  -- Reference BLAS level1 routine (version 3.4.0) --
   55: *  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
   56: *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
   57: *     November 2011
   58: *
   59: *     .. Scalar Arguments ..
   60:       INTEGER INCX,INCY,N
   61: *     ..
   62: *     .. Array Arguments ..
   63:       DOUBLE PRECISION DX(*),DY(*)
   64: *     ..
   65: *
   66: *  =====================================================================
   67: *
   68: *     .. Local Scalars ..
   69:       DOUBLE PRECISION DTEMP
   70:       INTEGER I,IX,IY,M,MP1
   71: *     ..
   72: *     .. Intrinsic Functions ..
   73:       INTRINSIC MOD
   74: *     ..
   75:       DDOT = 0.0d0
   76:       DTEMP = 0.0d0
   77:       IF (N.LE.0) RETURN
   78:       IF (INCX.EQ.1 .AND. INCY.EQ.1) THEN
   79: *
   80: *        code for both increments equal to 1
   81: *
   82: *
   83: *        clean-up loop
   84: *
   85:          M = MOD(N,5)
   86:          IF (M.NE.0) THEN
   87:             DO I = 1,M
   88:                DTEMP = DTEMP + DX(I)*DY(I)
   89:             END DO
   90:             IF (N.LT.5) THEN
   91:                DDOT=DTEMP
   92:             RETURN
   93:             END IF
   94:          END IF
   95:          MP1 = M + 1
   96:          DO I = MP1,N,5
   97:           DTEMP = DTEMP + DX(I)*DY(I) + DX(I+1)*DY(I+1) +
   98:      $            DX(I+2)*DY(I+2) + DX(I+3)*DY(I+3) + DX(I+4)*DY(I+4)
   99:          END DO
  100:       ELSE
  101: *
  102: *        code for unequal increments or equal increments
  103: *          not equal to 1
  104: *
  105:          IX = 1
  106:          IY = 1
  107:          IF (INCX.LT.0) IX = (-N+1)*INCX + 1
  108:          IF (INCY.LT.0) IY = (-N+1)*INCY + 1
  109:          DO I = 1,N
  110:             DTEMP = DTEMP + DX(IX)*DY(IY)
  111:             IX = IX + INCX
  112:             IY = IY + INCY
  113:          END DO
  114:       END IF
  115:       DDOT = DTEMP
  116:       RETURN
  117:       END